Sleep the card lora32u4

Hello, I have a BsFrance Lora32u4 II card, I measure temperature / humidity (DHT22) and battery level through cayenne, the program works fine but I want to minimize the current consumption, but I can not get down to 2mA.
I have tried with the LowPower.h library to sleep the Mega32u4 and also LMIC_shutdown () to sleep the RFM95 radio.

Someone with the LORA32u4 card has achieved a few uA consumption?

Thank you.

Greetings.

/*******************************************************************************
 * Copyright (c) 2015 Thomas Telkamp and Matthijs Kooijman
 *
 * Permission is hereby granted, free of charge, to anyone
 * obtaining a copy of this document and accompanying files,
 * to do whatever they want with them without any restriction,
 * including, but not limited to, copying, modification and redistribution.
 * NO WARRANTY OF ANY KIND IS PROVIDED.
 *
 * This example sends a valid LoRaWAN packet with static payload, 
 * using frequency and encryption settings matching those of
 * the (early prototype version of) The Things Network.
 *
 * Note: LoRaWAN per sub-band duty-cycle limitation is enforced (1% in g1,
 *  0.1% in g2).
 *
 * ToDo:
 * - set NWKSKEY (value from staging.thethingsnetwork.com)
 * - set APPKSKEY (value from staging.thethingsnetwork.com)
 * - set DEVADDR (value from staging.thethingsnetwork.com)
 * - optionally comment #define DEBUG
 * - optionally comment #define SLEEP
 * - set TX_INTERVAL in seconds
 * - change mydata to another (small) static text
 *
 *******************************************************************************/
#include <lmic.h>
#include <hal/hal.h>
#include <SPI.h>
#include <DHT.h>
#include <CayenneLPP.h>



#define MAX_SIZE 200 // depends on spreading factor and frequency used

CayenneLPP Payload(MAX_SIZE);

#define VBATPIN           A9
#define DHTPIN            10         // Pin which is connected to the DHT sensor.
#define DHTTYPE           DHT22     // DHT 22

DHT dht(DHTPIN, DHTTYPE);

unsigned long count;



// LoRaWAN NwkSKey, your network session key, 16 bytes (from staging.thethingsnetwork.org)
static const PROGMEM u1_t NWKSKEY[16] = { ****************** };

// LoRaWAN AppSKey, application session key, 16 bytes  (from staging.thethingsnetwork.org)
static const u1_t PROGMEM APPSKEY[16] = { ****************** };

// LoRaWAN end-device address (DevAddr), ie 0x91B375AC  (from staging.thethingsnetwork.org)
static const u4_t DEVADDR = { 0x********}; // <-- Change this address for every node!

// show debug statements; comment next line to disable debug statements
#define DEBUG
// use low power sleep; comment next line to not use low power sleep
#define SLEEP

// Schedule TX every this many seconds (might become longer due to duty
// cycle limitations).
const unsigned TX_INTERVAL = 1800;   

// static text, you can replace T
static uint8_t mydata[8] = { 0x03, 0x67, 0x01, 0x10, 0x05, 0x67, 0x00, 0xFF };

#ifdef SLEEP
#include "LowPower.h"
bool next = false;
#endif

// These callbacks are only used in over-the-air activation, so they are
// left empty here (we cannot leave them out completely unless
// DISABLE_JOIN is set in config.h, otherwise the linker will complain).
void os_getArtEui (u1_t* buf) { }
void os_getDevEui (u1_t* buf) { }
void os_getDevKey (u1_t* buf) { }

static osjob_t sendjob;

// Pin mapping
const lmic_pinmap lmic_pins = {
    .nss = 8,
    .rxtx = LMIC_UNUSED_PIN,
    .rst = 4,
    .dio = {7,6,LMIC_UNUSED_PIN},
};

void onEvent (ev_t ev) {
    #ifdef DEBUG
      Serial.println(F("Enter onEvent"));
    #endif
    
    switch(ev) {
        case EV_SCAN_TIMEOUT:
            Serial.println(F("EV_SCAN_TIMEOUT"));
            break;
        case EV_BEACON_FOUND:
            Serial.println(F("EV_BEACON_FOUND"));
            break;
        case EV_BEACON_MISSED:
            Serial.println(F("EV_BEACON_MISSED"));
            break;
        case EV_BEACON_TRACKED:
            Serial.println(F("EV_BEACON_TRACKED"));
            break;
        case EV_JOINING:
            Serial.println(F("EV_JOINING"));
            break;
        case EV_JOINED:
            Serial.println(F("EV_JOINED"));
            break;
        case EV_RFU1:
            Serial.println(F("EV_RFU1"));
            break;
        case EV_JOIN_FAILED:
            Serial.println(F("EV_JOIN_FAILED"));
            break;
        case EV_REJOIN_FAILED:
            Serial.println(F("EV_REJOIN_FAILED"));
            break;
        case EV_TXCOMPLETE:
            Serial.println(F("EV_TXCOMPLETE (includes waiting for RX windows)"));
            if(LMIC.dataLen) {
                // data received in rx slot after tx
                Serial.print(F("Data Received: "));
                Serial.write(LMIC.frame+LMIC.dataBeg, LMIC.dataLen);
                Serial.println();
            }
            // Schedule next transmission
#ifndef SLEEP
            os_setTimedCallback(&sendjob, os_getTime()+sec2osticks(TX_INTERVAL), do_send);
#else
            next = true;
#endif
            
            break;
        case EV_LOST_TSYNC:
            Serial.println(F("EV_LOST_TSYNC"));
            break;
        case EV_RESET:
            Serial.println(F("EV_RESET"));
            break;
        case EV_RXCOMPLETE:
            // data received in ping slot
            Serial.println(F("EV_RXCOMPLETE"));
            break;
        case EV_LINK_DEAD:
            Serial.println(F("EV_LINK_DEAD"));
            break;
        case EV_LINK_ALIVE:
            Serial.println(F("EV_LINK_ALIVE"));
            break;
         default:
            Serial.println(F("Unknown event"));
            break;
    }
    #ifdef DEBUG
      Serial.println(F("Leave onEvent"));
    #endif
    
}

void do_send(osjob_t* j){
    // Check if there is not a current TX/RX job running
    if (LMIC.opmode & OP_TXRXPEND) {
        Serial.println(F("OP_TXRXPEND, not sending"));
    } else {
        // Prepare upstream data transmission at the next possible time. 
      Payload.reset();
      
      // Get temperature event and print its value.

      int temp = dht.readTemperature(false);
      if (isnan(temp)) {
        Serial.println(F("Error reading temperature!"));
      }
      else {
        Serial.print(F("Temperature: "));
        Serial.print(temp);
        Serial.println(F(" *C"));
      }
      
      // Get humidity event and print its value.
      int humidity = dht.readHumidity();
      if (isnan(humidity)) {
        Serial.println("Error reading humidity!");
      }
      else {
        Serial.print(F("Humidity: "));
        Serial.print(humidity);
        Serial.println(F("%"));
      }
      
      float measuredvbat = analogRead(VBATPIN);
      measuredvbat *= 2;    // we divided by 2, so multiply back
      measuredvbat *= 3.3;  // Multiply by 3.3V, our reference voltage
      measuredvbat /= 1024; // convert to voltage
      Serial.print("VBat: " ); Serial.println(measuredvbat);
      
       Payload.addTemperature(0, temp);
       Payload.addRelativeHumidity(1, humidity);
       Payload.addAnalogInput(2, measuredvbat);
       
      LMIC_setTxData2(1, Payload.getBuffer(), Payload.getSize(), 0);
      Serial.println(F("Packet queued"));
      // Next TX is scheduled after TX_COMPLETE event.
    }

}

//-------------------------------------------------------SETUP-----------------------------------------------------

void setup() {
    delay(2500);
   
    Serial.begin(115200);
    Serial.println(F("Enter setup"));
    //FreqCount.begin(1000);
    
    #ifdef VCC_ENABLE
    // For Pinoccio Scout boards
    pinMode(VCC_ENABLE, OUTPUT);
    digitalWrite(VCC_ENABLE, HIGH);
    delay(1000);
    #endif

    // LMIC init
    os_init();
    
    // Reset the MAC state. Session and pending data transfers will be discarded.
    LMIC_reset();

    // Set static session parameters. Instead of dynamically establishing a session
    // by joining the network, precomputed session parameters are be provided.
    #ifdef PROGMEM
    // On AVR, these values are stored in flash and only copied to RAM
    // once. Copy them to a temporary buffer here, LMIC_setSession will
    // copy them into a buffer of its own again.
    uint8_t appskey[sizeof(APPSKEY)];
    uint8_t nwkskey[sizeof(NWKSKEY)];
    memcpy_P(appskey, APPSKEY, sizeof(APPSKEY));
    memcpy_P(nwkskey, NWKSKEY, sizeof(NWKSKEY));
    LMIC_setSession (0x1, DEVADDR, nwkskey, appskey);
    #else
    // If not running an AVR with PROGMEM, just use the arrays directly 
    LMIC_setSession (0x1, DEVADDR, NWKSKEY, APPSKEY);
    #endif

    // Set up the channels used by the Things Network, which corresponds
    // to the defaults of most gateways. Without this, only three base
    // channels from the LoRaWAN specification are used, which certainly
    // works, so it is good for debugging, but can overload those
    // frequencies, so be sure to configure the full frequency range of
    // your network here (unless your network autoconfigures them).
    // Setting up channels should happen after LMIC_setSession, as that
    // configures the minimal channel set.
   // LMIC_setupChannel(0, 903900000, DR_RANGE_MAP(DR_SF10, DR_SF7),  BAND_CENTI);      // g-band
   // LMIC_setupChannel(1, 904100000, DR_RANGE_MAP(DR_SF10, DR_SF7), BAND_CENTI);      // g-band
   // LMIC_setupChannel(2, 904300000, DR_RANGE_MAP(DR_SF10, DR_SF7),  BAND_CENTI);      // g-band
   // LMIC_setupChannel(3, 904500000, DR_RANGE_MAP(DR_SF10, DR_SF7),  BAND_CENTI);      // g-band
   // LMIC_setupChannel(4, 904700000, DR_RANGE_MAP(DR_SF10, DR_SF7),  BAND_CENTI);      // g-band
   // LMIC_setupChannel(5, 904900000, DR_RANGE_MAP(DR_SF10, DR_SF7),  BAND_CENTI);      // g-band
   // LMIC_setupChannel(6, 905100000, DR_RANGE_MAP(DR_SF10, DR_SF7),  BAND_CENTI);      // g-band
  //  LMIC_setupChannel(7, 905300000, DR_RANGE_MAP(DR_SF10, DR_SF7),  BAND_CENTI);      // g-band
  //  LMIC_setupChannel(8, 904600000, DR_RANGE_MAP(DR_SF8,  DR_SF8),  BAND_CENTI);      // g2-band
    // TTN defines an additional channel at 869.525Mhz using SF9 for class B
    // devices' ping slots. LMIC does not have an easy way to define set this
    // frequency and support for class B is spotty and untested, so this
    // frequency is not configured here.

    // Disable link check validation
    LMIC_setLinkCheckMode(0);

    LMIC_setAdrMode(false);
    
    LMIC.dn2Dr = DR_SF9;
    // Set data rate and transmit power (note: txpow seems to be ignored by the library)
    LMIC_setDrTxpow(DR_SF7,14);

    // Start job
    do_send(&sendjob);
    
    #ifdef DEBUG
      Serial.println(F("Leave setup"));
    #endif
}

//---------------------------------------------------------LOOP--------------------------------------------------

void loop() {

#ifndef SLEEP

  os_runloop_once();
  
#else
  extern volatile unsigned long timer0_overflow_count;

  if (next == false) {

    os_runloop_once();

  } else {

    int sleepcycles = TX_INTERVAL / 8;  // calculate the number of sleepcycles (8s) given the TX_INTERVAL
    #ifdef DEBUG
      Serial.print(F("Enter sleeping for "));
      Serial.print(sleepcycles);
      Serial.println(F(" cycles of 8 seconds"));
    #endif
    Serial.flush(); // give the serial print chance to complete
    delay(1000);
    //LMIC_shutdown();
    for (int i=0; i<sleepcycles; i++) {
      // Enter power down state for 8 s with ADC and BOD module disabled
      LMIC_shutdown();     
      LowPower.powerDown(SLEEP_8S, ADC_OFF, BOD_OFF);
      //LowPower.idle(SLEEP_8S, ADC_OFF, TIMER2_OFF, TIMER1_OFF, TIMER0_OFF, SPI_OFF, USART0_OFF, TWI_OFF);
      // LMIC uses micros() to keep track of the duty cycle, so
      // hack timer0_overflow for a rude adjustment:
      
      cli();
      timer0_overflow_count+= 8 * 64 * clockCyclesPerMicrosecond();
      sei();
    }
    //os_init();
    #ifdef DEBUG
      Serial.println(F("Sleep complete"));
    #endif
    next = false;
    // Start job
    do_send(&sendjob);
  } 
#endif
}
1 Like

@javialvar I don’t have experience with this PCB, but I went through something similar with the Adafruit Feather. In order to achieve minimum energy consumption I had to replace a voltage regulator that had a fairly large leakage current, en there was also a resistor bridge between Vcc and GND that leaked a substantial amount of current, where I replaced the Kohm values by Mohm equivalents.
And then of course you have to get the proper software configuration where you need to make sure that the relevant peripherals (like the AD-converter, USB-port, etc.) are switched off before you put the processor in sleep mode.

2 Likes

You can try with an RTC and PinChangeInterrupt.
Deep sleep, and wake up with an interrupt from RTC. Works fine.

2 Likes

I’ve used this board and had good results with switchting the AD-converter off before putting the processor in sleep mode.

e.g.

          Serial.println("start sleep");
          Serial.flush();
          ADCSRA = 0;
          for (int i = 0; i < 300; i++) { 
           Watchdog.sleep(1000);
          
          }
          Serial.println("wake up");
          ADCSRA = 1;
1 Like

This is already done by LowPower.h

LowPower.powerDown(SLEEP_8S, ADC_OFF, BOD_OFF);

I get around 200µA (without sensor).
Long story short, it depends the way you power the board (USB, BATT or 3v3 pin).
Big LoRa32u4 boards topic

Hi guys

Could you write shortly, what can be done to do minimum minimorum power consumption with uses of BAT socket (I connect moble phone 3.7V battery)?

I constructed a wireless temp sensor (d18B20) but consumption at start is about 20mA, then its rises to 35-40mA (radio and board sleep mode!!), and up to 50-60mA during sensor reading and transmit.

d18b20 uses resistor 10kOm to work and its permanently connected, but when i disconnect it, power stays ± at the same levels.

Thanks!