Hello,
can someone please point me to actually working example how to connect Wisen Whisper Node LoRa to TTN? (ABP or OTAA, I dont mind at the moment.)
I had minimal problem doing same with the Adafruit Feather 32u4 LoRa, but with Whisper Node I cannot find a single example.
Thanks in advance.
I did read the whole page of documentation:
Downloaded Talk2 Library from Bitbucket and try out examples:
Blink.nonBlocking, PowerDown.wakePeriodic and Voltage.node
Voltage.node is trasmiting data, but not to TTN.
I have tried to customize helloLora example from TinyLora library by changing the pin numbers, but without luck. It just does not send any data to TTN Console.
I have found tutorial here:
https://www.thethingsnetwork.org/docs/devices/uno/
It looks like excelent tutorial, but does not work with Whisper node.
I just need one working example to understand how it should look, but for uknown reason I cant find a single example 
true… that tutorial will never work, you need code with an Arduino-LMIC library and possibly add an extra wire to the board.
did you contact the seller/maker ?
and they are all different things.
You’ll need LMIC code and probably bridge a jumper.
Curious to see how they answer on your forum question there.
Overall its not the easiest way to start with ttn/ lorawan.
I got whisper node working for US915 … I did solder jumpers JP15 and JP16 for DIO1 (A2) and DIO2 (A3).
Use this LMIC library… it fits in the atmega 328 memory.
open lmic/config.h and make sure your region and radio is properly selected. CFG_us915 for me and CFG_sx1276_radio
Use the ttn-otaa sketch (make sure to register your application in TTN on the server as your gateway (us west for me)
When you are updating your keys in the sketch you must hit the reverse button to get your app eui and dev eui in lsb format. THIS is because it is an avr board
Pin mapping should look like this
// Pin mapping
const lmic_pinmap lmic_pins = {
.nss = 10,
.rxtx = LMIC_UNUSED_PIN,
.rst = 7,
.dio = {2, A2, A3},
};
LMIC_reset();
LMIC_setLinkCheckMode(1);
LMIC_setDrTxpow(DR_SF7,14);
LMIC_selectSubBand(1);
LMIC_setAdrMode(1);
Modify sketch for low power
//add these lines near the top of the sketch
#include <T2WhisperNode.h>
#include <LowPower.h>
T2Flash myFlash;
//replace the os_setTimedCallback line with this
//os_setTimedCallback(&sendjob, os_getTime() + sec2osticks(TX_INTERVAL), do_send);
for (int i=0; i<int(TX_INTERVAL/8); i++) {
// Use library from https://github.com/rocketscream/Low-Power
Serial.println(F(“looping”));
Serial.flush();
LowPower.powerDown(SLEEP_8S, ADC_OFF, BOD_OFF);
}
do_send(&sendjob);
//Add these lines in the void setup() section
// Flash - We’re not using, so just power it down to save energy
myFlash.init(T2_WPN_FLASH_SPI_CS);
myFlash.powerDown();
Here’s my example
/*******************************************************************************
* Copyright (c) 2015 Thomas Telkamp and Matthijs Kooijman
*
* Permission is hereby granted, free of charge, to anyone
* obtaining a copy of this document and accompanying files,
* to do whatever they want with them without any restriction,
* including, but not limited to, copying, modification and redistribution.
* NO WARRANTY OF ANY KIND IS PROVIDED.
*
* This example sends a valid LoRaWAN packet with payload "Hello,
* world!", using frequency and encryption settings matching those of
* the The Things Network.
*
* This uses OTAA (Over-the-air activation), where where a DevEUI and
* application key is configured, which are used in an over-the-air
* activation procedure where a DevAddr and session keys are
* assigned/generated for use with all further communication.
*
* Note: LoRaWAN per sub-band duty-cycle limitation is enforced (1% in
* g1, 0.1% in g2), but not the TTN fair usage policy (which is probably
* violated by this sketch when left running for longer)!
* To use this sketch, first register your application and device with
* the things network, to set or generate an AppEUI, DevEUI and AppKey.
* Multiple devices can use the same AppEUI, but each device has its own
* DevEUI and AppKey.
*
* Do not forget to define the radio type correctly in config.h.
*
*******************************************************************************/
#include <lmic.h>
#include <hal/hal.h>
#include <SPI.h>
//These are located in the extras folder of hte Talk2 library https://bitbucket.org/talk2/talk2-library
#include <T2WhisperNode.h>
#include <LowPower.h>
// This sketch is built off of this sketch and library https://github.com/matthijskooijman/arduino-lmic/blob/master/examples/ttn-otaa/ttn-otaa.ino
T2Flash myFlash; //added for Whisper Node
// This EUI must be in little-endian format, so least-significant-byte
// first. When copying an EUI from ttnctl output, this means to reverse
// the bytes. For TTN issued EUIs the last bytes should be 0xD5, 0xB3,
// 0x70.
static const u1_t PROGMEM APPEUI[8]={ FILLMEIN }; //needs to be in lsb (hit the reverse button on TTN console)
void os_getArtEui (u1_t* buf) { memcpy_P(buf, APPEUI, 8);}
// This should also be in little endian format, see above.
static const u1_t PROGMEM DEVEUI[8]={ FILLMEIN }; //needs to in lsb (hit the reverse button on TTN console)
void os_getDevEui (u1_t* buf) { memcpy_P(buf, DEVEUI, 8);}
// This key should be in big endian format (or, since it is not really a
// number but a block of memory, endianness does not really apply). In
// practice, a key taken from ttnctl can be copied as-is.
// The key shown here is the semtech default key.
static const u1_t PROGMEM APPKEY[16] = { FILLMEIN }; //in msb format
void os_getDevKey (u1_t* buf) { memcpy_P(buf, APPKEY, 16);}
static uint8_t mydata[] = "hi"; //keep short to minimize data!
static osjob_t sendjob;
// Schedule TX every this many seconds (might become longer due to duty
// cycle limitations).
const unsigned TX_INTERVAL = 600; //600s = 10 minutes
// Pin mapping for Whisper Node. Make sure to solder J15 and J16 on back of board for the A2, A3 connections
const lmic_pinmap lmic_pins = {
.nss = 10,
.rxtx = LMIC_UNUSED_PIN,
.rst = 7,
.dio = {2, A2, A3},
};
void onEvent (ev_t ev) {
Serial.print(os_getTime());
Serial.print(": ");
switch(ev) {
case EV_SCAN_TIMEOUT:
Serial.println(F("EV_SCAN_TIMEOUT"));
break;
case EV_BEACON_FOUND:
Serial.println(F("EV_BEACON_FOUND"));
break;
case EV_BEACON_MISSED:
Serial.println(F("EV_BEACON_MISSED"));
break;
case EV_BEACON_TRACKED:
Serial.println(F("EV_BEACON_TRACKED"));
break;
case EV_JOINING:
Serial.println(F("EV_JOINING"));
break;
case EV_JOINED:
Serial.println(F("EV_JOINED"));
// Disable link check validation (automatically enabled
// during join, but not supported by TTN at this time).
LMIC_setLinkCheckMode(0);
break;
case EV_RFU1:
Serial.println(F("EV_RFU1"));
break;
case EV_JOIN_FAILED:
Serial.println(F("EV_JOIN_FAILED"));
break;
case EV_REJOIN_FAILED:
Serial.println(F("EV_REJOIN_FAILED"));
break;
break;
case EV_TXCOMPLETE:
Serial.println(F("EV_TXCOMPLETE (includes waiting for RX windows)"));
if (LMIC.txrxFlags & TXRX_ACK)
Serial.println(F("Received ack"));
if (LMIC.dataLen) {
Serial.println(F("Received "));
Serial.println(LMIC.dataLen);
Serial.println(F(" bytes of payload"));
}
// Schedule next transmission
//os_setTimedCallback(&sendjob, os_getTime() + sec2osticks(TX_INTERVAL), do_send);
for (int i=0; i<int(TX_INTERVAL/8); i++) {
// Use library from https://github.com/rocketscream/Low-Power
Serial.println(F("looping"));
Serial.flush();
LowPower.powerDown(SLEEP_8S, ADC_OFF, BOD_OFF);
}
do_send(&sendjob);
break;
case EV_LOST_TSYNC:
Serial.println(F("EV_LOST_TSYNC"));
break;
case EV_RESET:
Serial.println(F("EV_RESET"));
break;
case EV_RXCOMPLETE:
// data received in ping slot
Serial.println(F("EV_RXCOMPLETE"));
break;
case EV_LINK_DEAD:
Serial.println(F("EV_LINK_DEAD"));
break;
case EV_LINK_ALIVE:
Serial.println(F("EV_LINK_ALIVE"));
break;
default:
Serial.println(F("Unknown event"));
break;
}
}
void do_send(osjob_t* j){
// Check if there is not a current TX/RX job running
if (LMIC.opmode & OP_TXRXPEND) {
Serial.println(F("OP_TXRXPEND, not sending"));
} else {
// Prepare upstream data transmission at the next possible time.
LMIC_setTxData2(1, mydata, sizeof(mydata)-1, 0);
Serial.println(F("Packet queued"));
}
// Next TX is scheduled after TX_COMPLETE event.
}
void setup() {
Serial.begin(115200);
Serial.println(F("Starting"));
// Flash - We're not using, so just power it down to save energy
myFlash.init(T2_WPN_FLASH_SPI_CS);
myFlash.powerDown();
// LMIC init
os_init();
// Reset the MAC state. Session and pending data transfers will be discarded.
LMIC_reset();
LMIC_setLinkCheckMode(0); //turned off again.. i see its also in the EV_JOINED section...
LMIC_setDrTxpow(DR_SF7,14);// this is being ignored.. not sure why
LMIC_selectSubBand(1); //SubBand 1 for US915 TTN
LMIC_setAdrMode(0); // Turn off adaptive data rate
// Start job (sending automatically starts OTAA too)
do_send(&sendjob);
}
void loop() {
os_runloop_once();
}Hi @everhamme Your program works for me when I configure my gateway for region you mentioned i.e. US915.
However I am in Singapore region hence, could you advise:
what changes in your program should I make?
and here there are many options to chose for the frequency do you think it matters what I chose to make your program work?
This topic is five years old so chances of getting a useful reply seems low.
Strongly suggest you learn LoRaWAN as his program is just an implementation of LMIC that he configured - just like you can if you read the materials.
Short answer yes! Everyone should be aware of the legal requirements for RF TX in their region BEFORE starting to pump out EM radiation otherwise risk 
! You should look up recommended Freq plan and any peripheral requirements such as dwell time limits, Listen Before Talk requirements etc in the respective TTN/TTI docs and the LoRa-Alliance specifications…and due own due dilegence we are not lawyers/experts in global RF regulations 
If you do not undertsand these terms best read docs and do homework 1st…
Once you have evaluated and decided what fits you can then select the options for device operation (registration) and programme LMIC as required…